:- module(array,[array_create/3,array_create/4,
                 array_get/4,array_set/5,
                 array_height/2,array_width/2,array_legal/3,
                 array_print/1]).

%%%%%%%%%%%%%%%%%
% construction

array_create(M,N, Array) :- 
  functor(Array, a, M), 
  make_rows(M,N, Array).
make_rows(0,_, _):-!.
make_rows(I,N, A) :- 
  functor(Row, r, N), 
  arg(I, A, Row), 
  J is I - 1, 
  make_rows(J,N, A).


array_create(M, N, Item, Array) :- 
  functor(Array, a, M), 
  make_rows(M, N, Item, Array).
make_rows(0,_, _, _):-!.
make_rows(I,N, Item, A) :- 
  functor(Row, r, N), 
  make_cols(N, Item, Row),
  arg(I, A, Row), 
  J is I - 1, 
  make_rows(J,N, Item, A).

make_cols(0, _, _):-!.
make_cols(I, Item, Row) :- 
  arg(I, Row, Item), 
  J is I - 1, 
  make_cols(J, Item, Row).

%%%%%%%%%%%%%%%%%
% access

array_get(Array, M, N, I) :- 
  arg(M, Array, Row), 
  arg(N, Row, I).

array_set(Arr, M, N, Item, Arr1) :-
  functor(Arr, a, Arity),
  functor(Arr1, a, Arity),
  Arr =.. [a|Rs],
  Arr1 =.. [a|Rs1],
  elements(Rs, Rs1, M, Row1),
  arg(M, Arr, Row),
  Row =.. [r|Args],
  elements(Args, Args1, N, Item),
  Row1 =.. [r|Args1].

% local predicate _elements(Src,Dst, I, Item).
%
% preconditions:
%  - Src is a list of N elements
%  - Dst is a list of N unbound variables
%  - I<N
% postconditions:
%  - All elements of Dst are bound to 
%    the respective elements of Src,
%    except for the Ith one which is
%    left unbound and is unified with Item
 
elements([], [], _, _).
elements([_|As], [Item|As1], 1, Item) :-
  !,elements(As, As1, 0, Item).
elements([A|As], [A|As1], M, Item) :-
  N is M - 1,
  elements(As, As1, N, Item).

%%%%%%%%%%%%%%%%%%%%%%%%
% attributes

array_height(Array,M):-
  functor(Array, a, M). 
array_width(Array,N):-
  arg(1, Array, Row),
  functor(Row, r, N). 
array_legal(A,I,J):-
  I>0, J>0,
  array_height(A,M),
  array_width(A,N),
  I=<M, J=<N. 

  
%%%%%%%%%%%%%%%%%%%%%%%%
% output

array_print(Arr):-
  Arr =.. [a|Rs],
  print_rows(Rs).

print_rows([]).
print_rows([Row|T]):-
  Row =.. [r|Cols],
  print_cols(Cols),
  write('\n'),
  print_rows(T).

print_cols([]).
print_cols([H|T]):-
  write(H),
  write('\t\t'),
  print_cols(T).

%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
% test driver
goal:-
  array_create(4,4,[],W),
  array_height(W,M),
  array_width(W,N),
  array_legal(W,M,N),
  array_set(W,1,1,[a],W1),
  array_set(W1,1,2,[wa],W2),
  array_print(W2).